You have saved this notebook in a directory. The following command will tell you in which directory you saved this notebook.

To execute the command below, place the cursor in the cell below and press Shift+Enter

NotebookDirectory[]

The following command will set the above directory as a working directory for this notebook. Since the graph that I create below will be exported to this directory.

SetDirectory[NotebookDirectory[]]

I experimented I found out that a good view of the graph that I produced is from the following point.  I use this in the last command below.

VP={0.9309251513656115`,-3.031838195362718`,1.1795488627838389`}

In the following cell I produce several graphs and then put them together in a “house” that I displayed at the class web site.

s1=Plot3D[Abs[x],{x,-2,2},{y,-2,2},RegionFunction->Function[{x,y,z},And[1<(x^2)+(y^2),(x^2)+(y^2)<4]],
PlotStyle->{Red},PlotRange->All,BoxRatios->{1,1,1/2},PlotPoints->{100,100},Mesh->None]; 


s2=ParametricPlot3D[{Cos[t],Sin[t],s},{t,0,2 Pi},{s,0,1},RegionFunction->Function[{x,y,z},And[z<Abs[x]]],PlotStyle->{Opacity[.5]},PlotRange->All,BoxRatios->{1,1,1/2},PlotPoints->{100,100},Mesh->None];

s3=ParametricPlot3D[{2Cos[t],2Sin[t],s},{t,0,2 Pi},{s,0,2},RegionFunction->Function[{x,y,z},And[z<Abs[x]]],PlotStyle->{Opacity[.4]},PlotRange->All,BoxRatios->{1,1,1/2},PlotPoints->{100,100},Mesh->None];

annulus12house=Show[s1,s2,s3,Boxed->False,Axes->False,ImageSize->600,ViewPoint->VP]

Next, I will export the above graph as a png file that I can use on my web site.

Export["annulus12house.png",annulus12house]

I could have used gif or jpg or svg, all popular image file-types for use at web sites.  Interestingly, Mathematica does not produce a very good svg file.

Export["annulus12house.gif",annulus12house]

Export["annulus12house.jpg",annulus12house]

Export["annulus12house.svg",annulus12house]

The volume of the house pictured above is

2Integrate[Integrate[r Cos[θ] r,{r,1,2}],{θ,-(Pi/2),(Pi/2)}]

The average distance is to the fixed radius is

((2Integrate[Integrate[r Cos[θ] r,{r,1,2}],{θ,-(Pi/2),(Pi/2)}])/((2^2-1^2)Pi))

Interestingly this number is very close to 1

N[(28/(9 π))]

We could have done this calculation for any inner radius a and outer radius b. Then the average would be

FullSimplify[((2Integrate[Integrate[r Cos[θ] r,{r,a,b}],{θ,-(Pi/2),(Pi/2)}])/(((b^2)-(a^2))Pi))]

Can you explain the following limit?

Limit[((4 ((a^2)+a b+(b^2)))/(3 (a+b) π)),b->a]

Here is a question related to our first calculation. Taking the inner radius 1, which outer radius would produce the average value of the distance exactly equal to 1?  Using Mathematica the answer is:

Solve[((4 (1+b+(b^2)))/(3 (1+b) π))==1,b]

N[%]

((4 ((a^2)+a b+(b^2)))/(3 (a+b) π))/.{b->2}

Solve[((4 (4+2 a+(a^2)))/(3 (2+a) π))==1,a]

N[%]