It might be a good idea to evaluate the entire notebook before reading it. You can do it from the keyboard: Alt+v o, or from the go to the Menu item Evaluation, then: Evaluate Notebook.

Plot3D[x y,{x,0,1},{y,0,1}]

?RegionPlot

RegionPlot[And[0<x,x<1,0<y,y<1-x],{x,0,1},{y,0,1},ImageSize->200]

house=RegionPlot3D[And[0<x,x<1,0<y,y<1-x,0<z,z<x y],{x,-0.01,1},{y,-0.01,1},{z,-0.01,1/4},PlotPoints->{121,121,121},PlotStyle->{Opacity[0.4]},Mesh->False,ImageSize->250,AxesLabel->{x,y,z},AxesEdge->{{-1,-1},{-1,-1},{-1,-1}}]

Options[Plot3D]

Show[house]

Graphics[{Blue,Polygon[{{1,2},{3,5},{-3,4},{1,2}}]},Frame->True,PlotRange->{{-5,5},{-5,5}}]

x0=.25;Show[house,Graphics3D[{Blue,Polygon[{{x0,0,0},{x0,1-x0,0},{x0,1-x0,x0(1-x0)},{x0,0,0}}]}]]

Manipulate[Show[house,Graphics3D[{Blue,Polygon[{{x0,0,0},{x0,1-x0,0},{x0,1-x0,x0(1-x0)},{x0,0,0}}]}]],{{x0,0.5},0,1}]

A slight change in the roof

Plot3D[(Sqrt[x y]),{x,0,1},{y,0,1}]

houseS=RegionPlot3D[And[0<x,x<1,0<y,y<1-x,0<z,z<(Sqrt[x y])],{x,-0.01,1},{y,-0.01,1},{z,-0.01,1/2},PlotPoints->{151,151,151},PlotStyle->{Opacity[0.4]},Mesh->False,ImageSize->800,AxesLabel->{x,y,z},AxesEdge->{{-1,-1},{-1,-1},{-1,-1}},BoxRatios->{1,1,1/2}]

Show[houseS,ImageSize->250]

x0=.5;Show[houseS,Graphics3D[{Blue,Polygon[{{x0,0,0},{x0,1-x0,0},{x0,1-x0,(Sqrt[x0(1-x0)])},{x0,0,0}}]}],ImageSize->250]

It is more work to get this accurately.

Graphics[{Yellow,Polygon[Table[{Cos[t],Sin[t]},{t,0,(( Pi)/2),((2Pi)/150)}]]},PlotRange->{{-2,2},{-2,2}},Frame->True,ImageSize->200]

Graphics[{Yellow,Polygon[Append[Table[{Cos[t],Sin[t]},{t,0,(( Pi)/2),((2Pi)/150)}],{0,0}]]},PlotRange->{{-2,2},{-2,2}},Frame->True,ImageSize->200]

x0=.5;Show[houseS,Graphics3D[{Blue,Polygon[Append[Table[{x0,y,(Sqrt[x0 y])},{y,0,1-x0,(1/75)}],{x0,1-x0,0}]]}],ImageSize->250]

Manipulate[Show[houseS,Graphics3D[{Blue,Polygon[Append[Table[{x0,y,(Sqrt[x0 y])},{y,0,1-x0,(1/75)}],{x0,1-x0,0}]]}],ImageSize->250],{{x0,.5},0,1}]

Making an animation

It turns out that it is easier to work with the graph of the roof if we make it using the command ParametricPlot3D. In the command bellow I also wanted to emphasise the foundation. I did it using the command Graphics3D. I combined two command using Show.

houseS1=Show[ParametricPlot3D[{x,t (1-x),(Sqrt[x t (1-x)])},{x,0,1},{t,0,1},Mesh->False,PlotStyle->{Opacity[0.4]},PlotPoints->{51,51}],
Graphics3D[{Line[{{0,0,0},{1,0,0},{0,1,0},{0,0,0}}]}],PlotRange->{{0,1},{0,1},{0,1/2}},ImageSize->800]

Slices=Table[Show[houseS1,Graphics3D[{Blue,Polygon[Append[Table[{x0,y,(Sqrt[x0 y])},{y,0,1-x0,(1/75)}],{x0,1-x0,0}]]}],ImageSize->800],{x0,0,1,(1/50)}];

Show[Slices[[26]]]

Length[Slices]

NotebookDirectory[]

Above I produced  the object Slices. It is a list of 51 pictures. I can Export that list as an animated gif file. I do it in the command below. In fact I export the 26th picture in Slices separately to use it as a picture on the class website.

(* SetDirectory[NotebookDirectory[]]; 

Export["SlicesD.gif",Slices[[26]],"GIF","ImageSize"->800];

Export["SlicesAni.gif",Slices,"GIF","AnimationRepetitions"->Infinity,"ImageSize"->800,"DisplayDurations"->0.3] 
*)

It turns out that to calculate the double integral of (Sqrt[x y]) over the region {(x,y) : 0≤x≤1, 0≤y≤1-x} is little bit more difficult. The first integral is not difficult, please calculate it yourself.

FullSimplify[Integrate[(Sqrt[x y]),{y,0,1-x}],And[x>0,x<1]]

The second integral is more difficult:

FullSimplify[Integrate[(1-x)(Sqrt[1-x]) (Sqrt[x]),x],And[x>0,x<1]]

I will show how to do this integral by hand on the website.