Assignment 1

Problems by Branko Curgus

SetOptions[$FrontEndSession,Magnification->2]

Prolog to Problem 1. Two cylinders

This is a tribute to a problem that I was assigned as an undergraduate student in the mid-1970s at the Department of Mathematics of the University of Sarajevo.

The problem involves the intersection of two circular cylinders. The smaller cylinder is vertical with the equation: (x^2)+(y^2)=2x (this is the circle centered at (1,0) with the radius 1) and z is arbitrary.  The larger cylinder is horizontal with the equation: (x^2)+(z^2)=4 and y is arbitrary.  I do not recall exactly what I was asked to do with these two cylinders.  However, I remember well that I spent a lot of time trying to visualize the intersection. At that time I did not have access to any technology to help with visualization.

Since I do not recall what was the exact question related to these two cylinders I will calculate all quantities that come to mind related to this object.

Visualization

This is a convenient view point in the graph below which I determined through experimentation.

vp={1.3`,-2.4`,2.`}

cyl1=ParametricPlot3D[{2 ((Cos[t])^2),2 Cos[t]Sin[t],z},{t,-Pi/2,Pi/2},{z,-3,3},PlotStyle->Opacity[.8],Mesh-> None,PlotPoints->{100,100}];

cyl2=ParametricPlot3D[{ 2 Cos[t],y,2 Sin[t]},{y,-3.3,3.3},{t,0,2 Pi},PlotStyle->Opacity[.3],Mesh->{32,64}];

int1=ParametricPlot3D[{2 ((Cos[t])^2),2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])},{t,-Pi/2,Pi/2},PlotStyle->{Thickness[0.007],Blue}];
int2=ParametricPlot3D[{2 ((Cos[t])^2),2 Cos[t]Sin[t],-(Sqrt[4-4 ((Cos[t])^4)])},{t,-Pi/2,Pi/2},PlotStyle->{Thickness[0.007],Blue}];

cirh=ParametricPlot3D[{2 ((Cos[t])^2),2 Cos[t]Sin[t],0},{t,-Pi/2,Pi/2},PlotStyle->{Thickness[0.005],Red,Opacity[1]},Mesh-> None];

cirv=ParametricPlot3D[{2 Cos[t],0,2 Sin[t]},{t,-Pi/2,Pi/2},PlotStyle->{Thickness[0.005],Red,Opacity[1]},Mesh-> None];


CylCyl1=Show[cyl1,cyl2,int1,int2,(* cirh,cirv, *) PlotRange->{{-2.1,2.6},{-2.6,2.6},{-(Sqrt[5])-.3,(Sqrt[5])+.3}},AxesEdge->{{-1,-1},{1,-1},{1,1}},AxesLabel->{x,y,z},ImageSize->400,ViewPoint->vp]

sur1=ParametricPlot3D[(1-s){2 ((Cos[t])^2),2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])}+s{2 ((Cos[t])^2),-2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])},{t,0,Pi/2},{s,0,1},PlotStyle->Opacity[.9],Mesh-> {0,0},PlotPoints->{50,50}];sur2=ParametricPlot3D[(1-s){2 ((Cos[t])^2),2 Cos[t]Sin[t],-(Sqrt[4-4 ((Cos[t])^4)])}+s{2 ((Cos[t])^2),-2 Cos[t]Sin[t],-(Sqrt[4-4 ((Cos[t])^4)])},{t,0,Pi/2},{s,0,1},PlotStyle->Opacity[.9],Mesh-> None,PlotPoints->{50,50}];

sur3=ParametricPlot3D[(1-s){2 ((Cos[t])^2),2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])}+s{2 ((Cos[t])^2),2 Cos[t]Sin[t],-(Sqrt[4-4 ((Cos[t])^4)])},{t,-Pi/2,Pi/2},{s,0,1},PlotStyle->Opacity[.9],Mesh-> {0,0},PlotPoints->{100,100}];
int1=ParametricPlot3D[{2 ((Cos[t])^2),2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])},{t,-Pi/2,Pi/2},PlotStyle->{Thickness[0.007],Blue}];
int2=ParametricPlot3D[{2 ((Cos[t])^2),2 Cos[t]Sin[t],-(Sqrt[4-4 ((Cos[t])^4)])},{t,-Pi/2,Pi/2},PlotStyle->{Thickness[0.007],Blue}];
cir=ParametricPlot3D[{2 ((Cos[t])^2),2 Cos[t]Sin[t],0},{t,-Pi/2,Pi/2},PlotStyle->{Thickness[0.005],Red,Opacity[1]},Mesh-> None];

CylCyl2=Show[cyl2,sur1,sur2,sur3,int1,int2,PlotRange->{{-2.1,2.6},{-2.6,2.6},{-(Sqrt[5])-.3,(Sqrt[5])+.3}},AxesEdge->{{-1,-1},{1,-1},{1,1}},AxesLabel->{x,y,z},ImageSize->400,ViewPoint->vp]

CylCyl3=Show[sur1,sur2,sur3,int1,int2,PlotRange->{{-2.1,2.6},{-2.6,2.6},{-(Sqrt[5])-.3,(Sqrt[5])+.3}},AxesEdge->{{-1,-1},{1,-1},{1,1}},AxesLabel->{x,y,z},ImageSize->400,ViewPoint->vp]

sur1p=ParametricPlot3D[(1-s){2 ((Cos[t])^2),2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])}+s{2 ((Cos[t])^2),-2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])}+{.6,0,0},{t,0,Pi/2},{s,0,1},PlotStyle->Opacity[.9],Mesh-> {0,0},PlotPoints->{50,50}];sur2p=ParametricPlot3D[(1-s){2 ((Cos[t])^2),2 Cos[t]Sin[t],-(Sqrt[4-4 ((Cos[t])^4)])}+s{2 ((Cos[t])^2),-2 Cos[t]Sin[t],-(Sqrt[4-4 ((Cos[t])^4)])}+{.6,0,0},{t,0,Pi/2},{s,0,1},PlotStyle->Opacity[.9],Mesh-> None,PlotPoints->{50,50}];

sur3p=ParametricPlot3D[(1-s){2 ((Cos[t])^2),2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])}+s{2 ((Cos[t])^2),2 Cos[t]Sin[t],-(Sqrt[4-4 ((Cos[t])^4)])}+{-1,0,0},{t,-Pi/2,Pi/2},{s,0,1},PlotStyle->Opacity[.9],Mesh-> {0,0},PlotPoints->{100,100}];
int1=ParametricPlot3D[{2 ((Cos[t])^2),2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])},{t,-Pi/2,Pi/2},PlotStyle->{Thickness[0.007],Blue,Opacity[1]},Mesh-> None];
int2=ParametricPlot3D[{2 ((Cos[t])^2),2 Cos[t]Sin[t],-(Sqrt[4-4 ((Cos[t])^4)])},{t,-Pi/2,Pi/2},PlotStyle->{Thickness[0.007],Blue,Opacity[1]},Mesh-> None];


CylCyl4=Show[sur1p,sur2p,sur3p,int1,int2, PlotRange->{{-2.1,2.6},{-2.6,2.6},{-(Sqrt[5])-.3,(Sqrt[5])+.3}},AxesEdge->{{-1,-1},{1,-1},{1,1}},AxesLabel->{x,y,z},ImageSize->400,ViewPoint->vp]

Unwrapping

Each cylinder can be unwrapped to a plane. Hence the blue curve above and two surfaces bounded by the blue curve can be unwrapped into planes.

How to find the equation for the blue curve when unwrapped to a plane? The following picture can help.

Show[sur1p,sur2p,sur3p,ParametricPlot3D[{{2 Cos[τ],2 (Sqrt[(1-Cos[τ]) Cos[τ]]),2Sin[τ]}},{τ,-Pi/2,Pi/2},PlotStyle->{Blue,Thickness[0.01]}],ParametricPlot3D[{{2 Cos[τ],-2 (Sqrt[(1-Cos[τ]) Cos[τ]]),2Sin[τ]}},{τ,-Pi/2,Pi/2},PlotStyle->{Blue,Thickness[0.01]}],cirh,cirv,PlotRange->{{-2.1,2.6},{-2.6,2.6},{-(Sqrt[5])-.3,(Sqrt[5])+.3}},AxesEdge->{{-1,-1},{1,-1},{1,1}},AxesLabel->{x,y,z},ImageSize->400,ViewPoint->vp]

Large cylinder

Let us consider first unwrapping the blue curve into the plane by unwrapping the larger cylinder.  As the larger cylinder is unwrapped to a plane, the vertical red half-circle is unwrapped to a vertical line segment of length 2π.  The parametric equation of the top part of the blue curve is

{2 ((Cos[t])^2),2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])}

The equation of the red horizontal circle is

{2 ((Cos[t])^2),2 Cos[t]Sin[t],0}

and the blue curve is above the red horizontal circle and on the large cylinder whose top part is given by z=(Sqrt[4 - (x^2)]).

Now we will determine the equation of the top part of the blue curve in relation to the arc length on the vertical red circle.  Let P be the point on the vertical red circle such that s is the arc length between the point (2,0,0).  The coordinates of P are (2 Cos[s/2], 0, 2 Sin[s/2]). Which point on the blue curve has the same z-coordinate?  Call that point B. The point B has the same x-coordinate as P.  Thus,

2 Cos[s/2] = 2 ((Cos[t])^2)

Solving for t  we get

Solve[2 Cos[s/2] == 2 ((Cos[t])^2),t]

Substituting

t->ArcCos[(Sqrt[Cos[(s/2)]])]

in

{2 ((Cos[t])^2),2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])}

FullSimplify[{2 ((Cos[t])^2),2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])}/.{t->ArcCos[(Sqrt[Cos[(s/2)]])]},And[0<s,s<Pi]]

This expression can be further simplified to

{2 Cos[(s/2)],2 Sin[(s/4)] √(Csc[(s/2)] 2 Sin[(s/2)]Cos[(s/2)]),2 Sin[(s/2)]}

Thus, the blue point B is at the distance  2 (Sqrt[2])Sin[(s/4)] (Sqrt[Cos[(s/2)]])  from the point P.  Thus, when flattened the equation of the blue curve is as follows:

Plot[{2 (Sqrt[2]) (Sqrt[Cos[(s/2)]]) Sin[(s/4)],-2 (Sqrt[2]) (Sqrt[Cos[(s/2)]]) Sin[(s/4)]},{s,-Pi,Pi},PlotStyle->{{Thickness[0.008],Blue},{Thickness[0.008],Blue}}, AspectRatio->Automatic,Ticks->{Range[-Pi,Pi,(Pi/4)],Range[-1,1]},PlotRange-> {{-Pi-.1,Pi+.1},{-1.1,1.1}},ImageSize->400]

It is interesting to point out that the equivalent expression for the blue curve above is as follows

FullSimplify[2 √((1-Cos[s/2]) Cos[s/2])==2 (Sqrt[2]) (Sqrt[Cos[(s/2)]]) Sin[(s/4)],And[0<s,s<Pi]]

Small cylinder

Now we will unwrap the blue curve by unwrapping the smaller cylinder.  As a parameter we will take the arc length s along the horizontal red circle starting from (2,0,0). As before, call P the point on this circle such that the arc length between P and (2,0,0) is s. From the geometry of the unit circle it follows the polar angle θ for this point is θ = s/2.  Therefore this point is given as

{2 ((Cos[(s/2)])^2),2 Cos[(s/2)]Sin[(s/2)],0},

The parametric equation for the top part of the blue curve is

{2 ((Cos[t])^2),2 Cos[t]Sin[t],2(Sqrt[1- ((Cos[t])^4)])}

Thus the point on the blue curve vertically above the point P is

{2 ((Cos[(s/2)])^2),2 Cos[(s/2)]Sin[(s/2)],2(Sqrt[1- ((Cos[(s/2)])^4)])}.

Plot[{2(Sqrt[1- ((Cos[s/2])^4)]),-2(Sqrt[1- ((Cos[s/2])^4)])},{s,-Pi,Pi},PlotStyle->{{Thickness[0.008],Blue},{Thickness[0.008],Blue}}, AspectRatio->Automatic,Ticks->{Range[-Pi,Pi,(Pi/4)],Range[-2,2]},PlotRange->{{-Pi-.1,Pi+.1},{-2.1,2.1}},ImageSize->400]

Or, cutting the surface at the point (2,0,0).

Plot[{2(Sqrt[1- ((Cos[(Pi-τ)/2])^4)]),-2(Sqrt[1- ((Cos[(Pi-τ)/2])^4)])},{τ,-Pi,Pi},PlotStyle->{{Thickness[0.008],Blue},{Thickness[0.008],Blue}}, AspectRatio->Automatic,Ticks->{Range[-Pi,Pi,(Pi/4)],Range[-2,2]},PlotRange->{{-Pi-.1,Pi+.1},{-2.1,2.1}},ImageSize->400]

Calculations

The surface area of the eight-shaped region

This is the surface area on the larger cylinder. It is the transparent surface in the picture. The area is

TrigToExp[4 Integrate[2 (Sqrt[2]) (Sqrt[Cos[(s/2)]]) Sin[(s/4)],{s,0,Pi}]]

N[16 (Sqrt[2])-16 Log[1+(Sqrt[2])]]

A different way to calculate this surface is to use the surface integral.

Cross[D[{x,y,(Sqrt[4-(x^2)])},x],D[{x,y,(Sqrt[4-(x^2)])},y]]

Simplify[√({(x/(Sqrt[4-(x^2)])),0,1}.{(x/(Sqrt[4-(x^2)])),0,1}),x>0]

Solve[(x^2)+(y^2)==2 x,y]

Integrate[2 (Sqrt[(1/(4-(x^2)))]),{y,-(Sqrt[2 x-(x^2)]),(Sqrt[2 x-(x^2)])}]

TrigToExp[2Integrate[Integrate[2 (Sqrt[(1/(4-(x^2)))]),{y,-(Sqrt[2 x-(x^2)]),(Sqrt[2 x-(x^2)])}],{x,0,2}]]

N[%]

Exactly the same value.

The vertical surface area

We found the equation so we just integrate.

TrigToExp[4Integrate[2(Sqrt[1- ((Cos[s/2])^4)]),{s,0,Pi}]]

N[8 (Sqrt[2])-4 Log[2]+8 Log[2+(Sqrt[2])]]

This expression can be simplified by hand to

8 (Sqrt[2])+4 Log[3+2(Sqrt[2])]

N[8 (Sqrt[2])+4 Log[3+2 (Sqrt[2])]]

It is interesting to point out that the above formula for the blue curve has equivalent form as follows:

FullSimplify[2(Sqrt[1- ((Cos[s/2])^4)])==(Sqrt[4-(((1+Cos[s]))^2)])]

TrigToExp[2Integrate[(Sqrt[4-(((1+Cos[t]))^2)]),{t,0,2Pi}]]

N[8 (Sqrt[2])-4 Log[1-(1/(Sqrt[2]))]+4 Log[1+(1/(Sqrt[2]))]]

A different way to calculate this surface is to use the surface integral.  I was not able to get the exact value in this way, just an approximation.

To get equation for the surface

Solve[(((x-1))^2)+(y^2)==1,y]

FullSimplify[Cross[D[{x,z,(Sqrt[2 x-(x^2)])},x],D[{x,z,(Sqrt[2 x-(x^2)])},z]]]

Simplify[√({((-1+x)/(Sqrt[-(-2+x) x])),0,1}.{((-1+x)/(Sqrt[-(-2+x) x])),0,1}),x>0]

We need to integrate this quantity over the half circle in xz-plane

(* Integrate[Integrate[(Sqrt[(1/(2 x-(x^2)))]),{x,0,(Sqrt[4-(y^2)])}],{y,-2,2}] *)

But this integral is not evaluating.

Try for the indefinite integral, that is anti-derivative:

FullSimplify[Integrate[(Sqrt[(1/(2 x-(x^2)))]),x],And[x>0,x<2]]

Now use the Fundamental Theorem of Calculus

FullSimplify[(2 I Log[(Sqrt[-2+x])+(Sqrt[x])]/.{x->(Sqrt[4-(y^2)])})-(2 I Log[(Sqrt[-2+x])+(Sqrt[x])]/.{x->0}),And[y>-2,x<2]]

And integrate numerically:

Chop[2NIntegrate[π-I Log[2]+2 I Log[(((4-(y^2)))^(1/4))+(Sqrt[-2+(Sqrt[4-(y^2)])])],{y,-2,2}]]

The volume

To calculate the volume we integrate the big cylinder over the small disk:

TrigToExp[2 Integrate[Integrate[(Sqrt[4-(x^2)]),{y,-(Sqrt[2 x-(x^2)]),(Sqrt[2 x-(x^2)])}],{x,0,2}]]

N[((44 (Sqrt[2]))/3)-12 Log[1+(Sqrt[2])]]

Or the small cylinder over the big half-circle. I was not able to get the exact value in this way.

(* TrigToExp[2 Integrate[Integrate[(Sqrt[2 x-(x^2)]),{x,0,(Sqrt[4-(z^2)])}],{z,-2,2}]] *)

Integrate[(Sqrt[2 x-(x^2)]),{x,0,(Sqrt[4-(z^2)])},Assumptions->And[z>0,z<2]]

4NIntegrate[(1/2) (((4-(z^2)))^(1/4)) (Sqrt[2-(Sqrt[4-(z^2)])]) (-1+(Sqrt[4-(z^2)]))+ArcSin[((((4-(z^2)))^(1/4))/(Sqrt[2]))],{z,0,2}]

The length of the blue curve:

We first use the first parametrization in the plane obtained above:

FullSimplify[√(1+(((D[2 (Sqrt[2]) (Sqrt[Cos[(s/2)]]) Sin[(s/4)],s]))^2))]

4NIntegrate[(1/2) (Sqrt[3+2 Cos[s]+Sec[(s/2)]]),{s,0,Pi}]

The second parametrization in the plane

FullSimplify[√(1+(((D[2(Sqrt[1- ((Cos[s/2])^4)]),s]))^2))]

4NIntegrate[((Sqrt[9-(16/(3+Cos[s]))+Cos[2 s]])/(Sqrt[2])),{s,0,Pi}]

Finally we use the parametrization of the blue curve in space:

{2 ((Cos[t])^2),2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])}

FullSimplify[D[{2 ((Cos[t])^2),2 Cos[t]Sin[t],(Sqrt[4-4 ((Cos[t])^4)])},t]]

FullSimplify[{-4 Cos[t] Sin[t],2 Cos[2 t],((4 ((Cos[t])^3) Sin[t])/(Sqrt[1-((Cos[t])^4)]))}.{-4 Cos[t] Sin[t],2 Cos[2 t],((4 ((Cos[t])^3) Sin[t])/(Sqrt[1-((Cos[t])^4)]))}]

2NIntegrate[√(2 (9-(16/(3+Cos[2 t]))+Cos[4 t])),{t,-Pi/2,Pi/2}]

One more parametrization in space

D[{2 Cos[(s/2)],2 (Sqrt[2]) (Sqrt[Cos[(s/2)]]) Sin[(s/4)],2 Sin[(s/2)]},s]

FullSimplify[{-Sin[(s/2)],((Cos[(s/4)] (Sqrt[Cos[(s/2)]]))/(Sqrt[2]))-((Sin[(s/4)] Sin[(s/2)])/((Sqrt[2]) (Sqrt[Cos[(s/2)]]))),Cos[(s/2)]}.{-Sin[(s/2)],((Cos[(s/4)] (Sqrt[Cos[(s/2)]]))/(Sqrt[2]))-((Sin[(s/4)] Sin[(s/2)])/((Sqrt[2]) (Sqrt[Cos[(s/2)]]))),Cos[(s/2)]}]

4NIntegrate[√(1+(1/2) ((Cos[((3 s)/4)])^2) Sec[(s/2)]),{s,0,Pi}]

Problem 1: Your task

Repeat as much as you can of what I did in Prolog to Problem 1 when the large Cylinder is replaced by the sphere of radius 2 centered at the origin

vp1={2.3282608341156705`,-2.0910863126772923`,1.2870740154539233`}

cyl1=ParametricPlot3D[{2 ((Cos[t])^2),2 Cos[t]Sin[t],z},{t,-Pi/2,Pi/2},{z,-3,3},PlotStyle->{Opacity[1]},Mesh-> None,PlotPoints->{100,100}];

sph=ParametricPlot3D[{ 2 Cos[θ] Sin[ϕ],2 Sin[θ] Sin[ϕ],2 Cos[ϕ]},{θ,0,2 Pi},{ϕ,0, Pi},PlotStyle->Opacity[.6],Mesh->{48,24}];

CylSph1=Show[cyl1,sph, PlotRange->{{-2.1,2.6},{-2.6,2.6},{-(Sqrt[5])-.3,(Sqrt[5])+.3}},AxesEdge->{{-1,-1},{1,-1},{1,1}},AxesLabel->{x,y,z},ImageSize->400,ViewPoint->vp1]

Prolog to Problem 2. Two famous multiple integrals

A famous double integral

Consider the integral  (∫_0^1)(∫_0^1)(1/(1-(((x y))^2)))dxdy.

Mathematica does calculate this integral.

Integrate[Integrate[(1/(1-(x^2)(y^2))),{x,0,1}],{y,0,1}]

However, calculating this integral by hand using the Fundamental theorem of calculus is not easy. Here is why

Integrate[(1/(1-(x^2)(y^2))),x]

This is doable by hand. Now we apply the FTC and get

(((ArcTanh[x y])/y)/.{x->1})-(((ArcTanh[x y])/y)/.{x->0})

Next we integrate

Integrate[((ArcTanh[y])/y),y]

But this integral is a special function that is not familiar to an undergraduate student. In fact this is not often studied function.

Applying FTC again we get.

(((1/2) (-PolyLog[2,-y]+PolyLog[2,y]))/.{y->1})-(((1/2) (-PolyLog[2,-y]+PolyLog[2,y]))/.{y->0})

Our goal is to understand this result using change of variables in double integral.

We use the following change of variables:

x = ((u+v)/(1+u v)), y=((u-v)/(1-u v))

Good way to think about this change of variables is as a mapping from uv-plane into xy-plane.

{u,v}   is being mapped in    {((u+v)/(1+u v)),((u-v)/(1-u v))}

One way to visualize this mapping is to plot the grid of coordinate lines in uv-plane and map them into  curves in xy-plane. For example the line u=1/2 is being mapped into the curve {(((1/2)+v)/(1+(1/2) v)),(((1/2)-v)/(1-(1/2) v))}

GraphicsGrid[
{{
Graphics[{
Table[
{Hue[((u+2)/4)],Line[{{u,-5},{u,5}}]},{u,-2,2,.25}]
},
PlotRange->{{-2,2},{-2,2}},Frame->True,ImageSize->225,FrameLabel->{"u","v"},RotateLabel->False
],
Graphics[{
Table[
{Hue[((u+2)/4)],PointSize[0.007],Table[Point[{((u+v)/(1+u v)), ((u-v)/(1-v u))}],{v,-5,5,(Pi/100)}]},{u,-2,2,.25}]

},
PlotRange->{{-2,2},{-2,2}},Frame->True,ImageSize->225,
FrameLabel->{"x","y"},RotateLabel->False
]
}}]

GraphicsGrid[
{{
Graphics[{
Table[
{Hue[((v+2)/4)],Line[{{-5,v},{5,v}}]},{v,-2,2,.25}]
},
PlotRange->{{-2,2},{-2,2}},Frame->True,ImageSize->225,FrameLabel->{"u","v"},RotateLabel->False
],
Graphics[{
Table[
{Hue[((v+2)/4)],PointSize[0.007],Table[Point[{((u+v)/(1+u v)), ((u-v)/(1-v u))}],{u,-5,5,(Pi/100)}]},{v,-2,2,.25}]

},
PlotRange->{{-2,2},{-2,2}},Frame->True,ImageSize->225,
FrameLabel->{"x","y"},RotateLabel->False
]
}}]

Since we see some overlap it is clear that we will have to narrow down the area in uv-plane.

GraphicsGrid[
{{
Graphics[{
Table[
{Hue[((u+1)/4)],Thickness[0.01],Line[{{u,-1},{u,1}}]},{u,-0.975,1,.05}]
},
PlotRange->{{-1,1},{-1,1}},Frame->True,ImageSize->225,FrameLabel->{"u","v"},RotateLabel->False
],
Graphics[{
Table[
{Hue[((u+1)/4)],Thickness[0.01],Line[Table[{((u+v)/(1+u v)), ((u-v)/(1-v u))},{v,-1,1,(Pi/100)}]]},{u,-.975,1,.05}]

},
PlotRange->{{-1,1},{-1,1}},Frame->True,ImageSize->225,
FrameLabel->{"x","y"},RotateLabel->False
]
}}]

GraphicsGrid[
{{
Graphics[{
Table[
{Hue[((v+3)/4)],Thickness[0.01],Line[{{-1,v},{1,v}}]},{v,-0.975,1,.05}]
},
PlotRange->{{-1,1},{-1,1}},Frame->True,ImageSize->225,FrameLabel->{"u","v"},RotateLabel->False
],
Graphics[{
Table[
{Hue[((v+3)/4)],Thickness[0.01],Line[Table[{((u+v)/(1+u v)), ((u-v)/(1-v u))},{u,-1,1,(Pi/100)}]]},{v,-0.975,1,.05}]

},
PlotRange->{{-1,1},{-1,1}},Frame->True,ImageSize->225,
FrameLabel->{"x","y"},RotateLabel->False
]
}}]

GraphicsGrid[
{{
Graphics[{
Table[
{Hue[((u+1)/4)],Thickness[0.005],Line[{{u,-1},{u,1}}]},{u,-0.975,1,.05}],
Table[
{Hue[((v+3)/4)],Thickness[0.005],Opacity[0.5],Line[{{-1,v},{1,v}}]},{v,-0.975,1,.05}]
},
PlotRange->{{-1,1},{-1,1}},Frame->True,ImageSize->225,FrameLabel->{"u","v"},RotateLabel->False
],
Graphics[{
Table[
{Hue[((u+1)/4)],Thickness[0.005],Line[Table[{((u+v)/(1+u v)), ((u-v)/(1-v u))},{v,-1,1,(Pi/100)}]]},{u,-.975,1,.05}],
Table[
{Hue[((v+3)/4)],Thickness[0.005],Opacity[0.5],Line[Table[{((u+v)/(1+u v)), ((u-v)/(1-v u))},{u,-1,1,(Pi/100)}]]},{v,-0.975,1,.05}]

},
PlotRange->{{-1,1},{-1,1}},Frame->True,ImageSize->225,
FrameLabel->{"x","y"},RotateLabel->False
]
}}]

Just for fun

Manipulate[GraphicsGrid[
{{
Graphics[{
Table[
{Hue[(t/(2Pi))],Point[rr{Cos[t],Sin[t]}]},{t,0,2 Pi,(Pi/64)}]
},
PlotRange->{{-1,1},{-1,1}},Frame->True,ImageSize->225,FrameLabel->{"u","v"},RotateLabel->False
],
Graphics[{
Table[
{Hue[(t/(2Pi))],Point[rr{(Cos[t]+Sin[t])/(1+(((rr))^2)Cos[t] Sin[t]), (Cos[t]-Sin[t])/(1-(((rr))^2)Sin[t] Cos[t])}]},{t,0,2 Pi,(Pi/64)}]

},
PlotRange->{{-1,1},{-1,1}},Frame->True,ImageSize->225,
FrameLabel->{"x","y"},RotateLabel->False
]
}}],{{rr,.5},.1,.9}]

Manipulate[GraphicsGrid[
{{
Graphics[{
Table[
{Hue[(k/128)],Thickness[0.02],Line[{rr{Cos[k(Pi/64)],Sin[k(Pi/64)]},rr{Cos[(k+1)(Pi/64)],Sin[(k+1)(Pi/64)]}}]},{k,0,128-1,1}]
},
PlotRange->{{-1,1},{-1,1}},Frame->True,ImageSize->225,FrameLabel->{"u","v"},RotateLabel->False
],
Graphics[{
Table[
{Hue[(t/(2Pi))],Thickness[0.02],Line[{rr{(Cos[t]+Sin[t])/(1+(((rr))^2)Cos[t] Sin[t]), (Cos[t]-Sin[t])/(1-(((rr))^2)Sin[t] Cos[t])},rr{(Cos[t+(Pi/64)]+Sin[t+(Pi/64)])/(1+(((rr))^2)Cos[t+(Pi/64)] Sin[t+(Pi/64)]), (Cos[t+(Pi/64)]-Sin[t+(Pi/64)])/(1-(((rr))^2)Sin[t+(Pi/64)] Cos[t+(Pi/64)])}}]},{t,0,2 Pi-(Pi/64),(Pi/64)}]


},
PlotRange->{{-1,1},{-1,1}},Frame->True,ImageSize->225,
FrameLabel->{"x","y"},RotateLabel->False
]
}}],{{rr,.5},.01,.99}]

Let us go back to the change of variables:

x = ((u+v)/(1+u v)), y=((u-v)/(1-u v))

This is how Mathematica calculates the Jacobian matrix:

D[{((u+v)/(1+u v)), ((u-v)/(1-u v))},{{u,v}}]

We need the determinant of the Jacobian matrix

FullSimplify[Det[D[{((u+v)/(1+u v)), ((u-v)/(1-u v))},{{u,v}}]]]

We notice that this quantity is negative for u, v being in [-1,1]. So the absolute value is

FullSimplify[-Det[D[{((u+v)/(1+u v)), ((u-v)/(1-u v))},{{u,v}}]]]

We need to understand which set in uv-plane is being mapped onto the unit square with vertices (0,0), (1,0), (1,1), (1,0) in xy-plane.

Next we list points in uv-plane and their images in xy-plane 

(0,0)  goes to (0,0)
(1,1)  goes to (1,0) 
(1,-1)  goes to (0,1)
(1,0)  goes to (1,1)

This indicates that the triangle with vertices (0,0), (1,-1), (1,1) is being mapped onto the unit square. The following graphics confirms that.

GraphicsGrid[
{{
Graphics[{
Table[
{Hue[u],Line[Table[{u,v},{v,-u,u,.01}]]},{u,0,1-.001,.025}]
},
PlotRange->{{0,1},{-1,1}},Frame->True,ImageSize->200,FrameLabel->{"u","v"},RotateLabel->False
],
Graphics[{
Table[
{Hue[u],Line[Table[{((u+v)/(1+u v)), ((u-v)/(1-v u))},{v,-u,u,.01}]]},{u,0,1-.001,.025}]
},
PlotRange->{{0,1},{0,1}},Frame->True,ImageSize->225,
FrameLabel->{"x","y"},RotateLabel->False
]
}}]

Now we substitute the new variables into the integrand

FullSimplify[((1/(1-(x^2) (y^2)))/.{x-> ((u+v)/(1+u v)),y-> ((u-v)/(1-v u))})]

We notice that this quantity is positive. This expression needs to be multiplied by the absolute value of the determinant of the Jacobian matrix. Thus, the new integrand is

FullSimplify[((((-1+(u^2) (v^2)))^2)/((-1+(u^4)) (-1+(v^4))))(-Det[D[{((u+v)/(1+u v)), ((u-v)/(1-u v))},{{u,v}}]])]

So, we need to calculate the integral

(∫_0^1)(∫_(-u)^u)(2/((1+(u^2)) (1+(v^2))))dvdu.

This integral is easily calculable by hand.  However, for efficiency I do it in Mathematica here.

Integrate[(2/((1+(u^2)) (1+(v^2)))),{v,-u,u}]

Now we integrate with respect to u. This is also a simple change of variables integral.

Integrate[((4 ArcTan[u])/(1+(u^2))),{u,0,1}]

A famous triple integral

We consider the integral  (∫_0^1)(∫_0^1)(∫_0^1)(1/(1+(((x y z))^2)))dxdy dz.

Mathematica does calculate this integral.

Integrate[Integrate[Integrate[(1/(1+(x^2)(y^2)(z^2) )),{x,0,1}],{y,0,1}],{z,0,1}]

Our goal is to understand this result using change of variables in double integral.

The change of variables here is

x = ((Sin[u])/(Cos[v])), y=((Sin[v])/(Cos[w])), z = ((Sin[w])/(Cos[u]))

Good way to think about this change of variables is as a mapping from uvw-space into xyz-space.

{u,v,w}   is being mapped in   {((Sin[u])/(Cos[v])),((Sin[v])/(Cos[w])),((Sin[w])/(Cos[u]))}

This is how Mathematica calculates the Jacobian matrix:

D[{((Sin[u])/(Cos[v])),((Sin[v])/(Cos[w])),((Sin[w])/(Cos[u]))},{{u,v,w}}]

We need the determinant of the Jacobian matrix

FullSimplify[Det[D[{((Sin[u])/(Cos[v])),((Sin[v])/(Cos[w])),((Sin[w])/(Cos[u]))},{{u,v,w}}]]]

This function is always positive. So, no problems here.

We need to understand which set in uv-plane is being mapped onto the unit cube with the vertices (0,0,0), (1,0,0), (1,1,0), (1,0,0), (0,0,1), (1,0,1), (1,1,1), (1,0,1) in xyz-space.

Next we list points in uvw-space and their images in xyz-space 

(0,0,0)    goes to  (0,0,0)
((π/2),0,0)   goes to  (1,0,0) 
(0,(π/2),0)   goes to  (0,1,0)
(0,0,(π/2))   goes to  (0,0,1)
((π/4),(π/4),(π/4))  goes to  (1,1,1)

This indicates that the polytope with vertices (0,0,0), ((π/2),0,0), (0,(π/2),0), (0,0,(π/2),0), ((π/2),(π/2),(π/2)) is being mapped onto the unit cube. Our next goal is to confirm that. Here is the image of the polytope:

Graphics3D[{
{Blue,Thickness[0.007],Line[{{0,0,0},{(Pi/2),0,0},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{0,0,0},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{0,0,0},{0,0,(Pi/2)},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{(Pi/2),0,0},{0,(Pi/2),0},{0,0,(Pi/2)},{(Pi/2),0,0}}]},
{Opacity[0.6],Polygon[{{0,0,0},{0,0,(Pi/2)},{0,(Pi/2),0}}],Polygon[{{0,0,0},{(Pi/2),0,0},{0,(Pi/2),0}}],Polygon[{{0,0,(Pi/2)},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}],Polygon[{{(Pi/2),0,0},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}]},{Opacity[.2],Polygon[{{0,0,0},{(Pi/2),0,0},{0,0,(Pi/2)}}],Polygon[{{0,0,(Pi/2)},{(Pi/2),0,0},{(Pi/4),(Pi/4),(Pi/4)}}]}
},PlotRange->{{0,(Pi/2)},{0,(Pi/2)},{0,(Pi/2)}},Ticks->{Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4]},Boxed-> True,Axes->True,AxesLabel->{x,y,z},ImageSize->400]

This polytope can be described mathematically as

{ (x,y,z) ∈ (ℝ^3) | x>0, y> 0, z > 0, x+y<(π/2), y+z<(π/2), z+x <(π/2)}

Mathematica can plot this polytope using these inequalities:

RegionPlot3D[And[x>0,y>0,z>0,x+y<(Pi/2),y+z<(Pi/2),x+z<(Pi/2)],{x,0,(Pi/2)},{y,0,(Pi/2)},{z,0,(Pi/2)},PlotPoints->{65,65,65},PlotStyle->{Opacity[.5]},Mesh->False,AxesLabel->{x,y,z},Ticks->{Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4]}]

Next we will use Manipulate to slice this polytope into triangles which we will map into the unit cube.

Manipulate[
Graphics3D[{
{Blue,Thickness[0.007],Line[{{0,0,0},{(Pi/2),0,0},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{0,0,0},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{0,0,0},{0,0,(Pi/2)},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{(Pi/2),0,0},{0,(Pi/2),0},{0,0,(Pi/2)},{(Pi/2),0,0}}]},
{Opacity[0.6],Polygon[{{0,0,0},{0,0,(Pi/2)},{0,(Pi/2),0}}],Polygon[{{0,0,0},{(Pi/2),0,0},{0,(Pi/2),0}}],Polygon[{{0,0,(Pi/2)},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}],Polygon[{{(Pi/2),0,0},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}]},{Opacity[.2],Polygon[{{0,0,0},{(Pi/2),0,0},{0,0,(Pi/2)}}],Polygon[{{0,0,(Pi/2)},{(Pi/2),0,0},{(Pi/4),(Pi/4),(Pi/4)}}]},
{Opacity[1],
If[a<1,Polygon[{{a((Pi )/2),0,0},{0,a((Pi )/2),0},{0,0,a((Pi )/2)}}],Polygon[{(1-(a-1)){((Pi )/2),0,0}+(a-1){(Pi/4),(Pi/4),(Pi/4)},(1-(a-1)){0,((Pi )/2),0}+(a-1){(Pi/4),(Pi/4),(Pi/4)},(1-(a-1)){0,0,((Pi )/2)}+(a-1){(Pi/4),(Pi/4),(Pi/4)}}]]}
},
PlotRange->{{0,(Pi/2)},{0,(Pi/2)},{0,(Pi/2)}},Ticks->{Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4]},Boxed-> True,Axes->True,ImageSize->400],{{a,.5},0,2}]

In the above Manipulation I used Polygon command to draw the slicing triangles. For that I needed only the vertices of the triangles. However, to map the triangles into xyz-space I need to represent the triangles using two parameters s and t. How to do that?

If we have two points say A and B, then all the point on the line segment  AB are given by  (1-s) A + s B where 0 ≤ s ≤1 .

We use the same idea for three points, say A, B, C. First we represent all the points on the line segments AB and AC

(1-s) A + s B,   0 ≤ s ≤1  and    (1-s) A + s C,   0 ≤ s ≤1 .

Now for a fixed s I use parameter t to represent all the point on the line segment connecting the point

(1-s) A + s B   and    (1-s) A + s C :

(1-t)((1-s) A + s B)  +  t ((1-s) A + s C)   where   0 ≤ s, t ≤1 .

Simplifying the last expression we get the following formula for the surface of the triangle with vertices A, B, C

Clear[pA,pB,pC,s,t]; Collect[FullSimplify[(1-t)((1-s) pA +s pB)+t ((1-s) pA+s pC) ],{pA,pB,pC}]

Thus the formula

(1-s)A +s (1-t) B + s t C    where   0 ≤ s, t ≤1

represents the surface of the triangle with vertices A, B, C. I will illustrate this with a graphics:

Manipulate[
If[a<1,Show[Graphics3D[{
{Blue,Thickness[0.007],Line[{{0,0,0},{(Pi/2),0,0},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{0,0,0},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{0,0,0},{0,0,(Pi/2)},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{(Pi/2),0,0},{0,(Pi/2),0},{0,0,(Pi/2)},{(Pi/2),0,0}}]},
{Opacity[0.6],Polygon[{{0,0,0},{0,0,(Pi/2)},{0,(Pi/2),0}}],Polygon[{{0,0,0},{(Pi/2),0,0},{0,(Pi/2),0}}],Polygon[{{0,0,(Pi/2)},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}],Polygon[{{(Pi/2),0,0},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}]},{Opacity[.2],Polygon[{{0,0,0},{(Pi/2),0,0},{0,0,(Pi/2)}}],Polygon[{{0,0,(Pi/2)},{(Pi/2),0,0},{(Pi/4),(Pi/4),(Pi/4)}}]}
}],
ParametricPlot3D[(1-s){a((Pi )/2),0,0}+(1-t)s{0,a((Pi )/2),0}+(s t){0,0,a((Pi )/2)},{s,0,1},{t,0,1}],
PlotRange->{{0,(Pi/2)},{0,(Pi/2)},{0,(Pi/2)}},Ticks->{Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4]},Boxed-> True,Axes->True,ImageSize->300],

Show[Graphics3D[{
{Blue,Thickness[0.007],Line[{{0,0,0},{(Pi/2),0,0},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{0,0,0},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{0,0,0},{0,0,(Pi/2)},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{(Pi/2),0,0},{0,(Pi/2),0},{0,0,(Pi/2)},{(Pi/2),0,0}}]},
{Opacity[0.6],Polygon[{{0,0,0},{0,0,(Pi/2)},{0,(Pi/2),0}}],Polygon[{{0,0,0},{(Pi/2),0,0},{0,(Pi/2),0}}],Polygon[{{0,0,(Pi/2)},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}],Polygon[{{(Pi/2),0,0},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}]},{Opacity[.2],Polygon[{{0,0,0},{(Pi/2),0,0},{0,0,(Pi/2)}}],Polygon[{{0,0,(Pi/2)},{(Pi/2),0,0},{(Pi/4),(Pi/4),(Pi/4)}}]}
}],
ParametricPlot3D[(1-s)((1-(a-1)){((Pi )/2),0,0}+(a-1){(Pi/4),(Pi/4),(Pi/4)})+(1-t)s((1-(a-1)){0,((Pi )/2),0}+(a-1){(Pi/4),(Pi/4),(Pi/4)})+(s t)((1-(a-1)){0,0,((Pi )/2)}+(a-1){(Pi/4),(Pi/4),(Pi/4)}),{s,0,1},{t,0,1}],PlotRange->{{0,(Pi/2)},{0,(Pi/2)},{0,(Pi/2)}},Ticks->{Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4]},Boxed-> True,Axes->True,ImageSize->300]],{{a,.5},0,2}]

Next I use the mapping

{u,v,w}  is being mapped in  {((Sin[u])/(Cos[v])),((Sin[v])/(Cos[w])),((Sin[w])/(Cos[u]))}

Manipulate[If[a<1,ParametricPlot3D[Evaluate[{((Sin[u])/(Cos[v])),((Sin[v])/(Cos[w])),((Sin[w])/(Cos[u]))}/.{u-> (1/2) a π (1-s),v-> (1/2) a π s (1-t),w-> (1/2) a π s t}] ,{s,0,1},{t,0,1},PlotRange->{{0,1},{0,1},{0,1}},Ticks->{Range[0,1,.2],Range[0,1,.2],Range[0,1,.2]},Boxed-> True,Axes->True,ImageSize->300],ParametricPlot3D[Evaluate[{((Sin[u])/(Cos[v])),((Sin[v])/(Cos[w])),((Sin[w])/(Cos[u]))}/.{u-> (1/4) π (3-a+2 (-2+a) s),v-> (1/4) π (-1+a+4 s-2 a s+2 (-2+a) s t),w-> (1/4) π (-1+a-2 (-2+a) s t)}] ,{s,0,1},{t,0,1},PlotRange->{{0,1},{0,1},{0,1}},Ticks->{Range[0,1,.2],Range[0,1,.2],Range[0,1,.2]},Boxed-> True,Axes->True,ImageSize->300]],{{a,.5},0,2}]

Manipulate[If[a<1,
GraphicsGrid[
{{
Show[Graphics3D[{
{Blue,Thickness[0.007],Line[{{0,0,0},{(Pi/2),0,0},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{0,0,0},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{0,0,0},{0,0,(Pi/2)},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{(Pi/2),0,0},{0,(Pi/2),0},{0,0,(Pi/2)},{(Pi/2),0,0}}]},
{Opacity[0.6],Polygon[{{0,0,0},{0,0,(Pi/2)},{0,(Pi/2),0}}],Polygon[{{0,0,0},{(Pi/2),0,0},{0,(Pi/2),0}}],Polygon[{{0,0,(Pi/2)},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}],Polygon[{{(Pi/2),0,0},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}]},{Opacity[.2],Polygon[{{0,0,0},{(Pi/2),0,0},{0,0,(Pi/2)}}],Polygon[{{0,0,(Pi/2)},{(Pi/2),0,0},{(Pi/4),(Pi/4),(Pi/4)}}]}
}],
ParametricPlot3D[(1-s){a((Pi )/2),0,0}+(1-t)s{0,a((Pi )/2),0}+(s t){0,0,a((Pi )/2)},{s,0,1},{t,0,1}],
PlotRange->{{0,(Pi/2)},{0,(Pi/2)},{0,(Pi/2)}},Ticks->{Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4]},Boxed-> True,Axes->True,ImageSize->600],ParametricPlot3D[Evaluate[{((Sin[u])/(Cos[v])),((Sin[v])/(Cos[w])),((Sin[w])/(Cos[u]))}/.{u-> (1/2) a π (1-s),v-> (1/2) a π s (1-t),w-> (1/2) a π s t}] ,{s,0,1},{t,0,1},PlotRange->{{0,1},{0,1},{0,1}},Ticks->{Range[0,1,.2],Range[0,1,.2],Range[0,1,.2]},Boxed-> True,Axes->True,ImageSize->600]
}},ImageSize->500],
GraphicsGrid[
{{
Show[Graphics3D[{
{Blue,Thickness[0.007],Line[{{0,0,0},{(Pi/2),0,0},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{0,0,0},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{0,0,0},{0,0,(Pi/2)},{(Pi/4),(Pi/4),(Pi/4)}}],Line[{{(Pi/2),0,0},{0,(Pi/2),0},{0,0,(Pi/2)},{(Pi/2),0,0}}]},
{Opacity[0.6],Polygon[{{0,0,0},{0,0,(Pi/2)},{0,(Pi/2),0}}],Polygon[{{0,0,0},{(Pi/2),0,0},{0,(Pi/2),0}}],Polygon[{{0,0,(Pi/2)},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}],Polygon[{{(Pi/2),0,0},{0,(Pi/2),0},{(Pi/4),(Pi/4),(Pi/4)}}]},{Opacity[.2],Polygon[{{0,0,0},{(Pi/2),0,0},{0,0,(Pi/2)}}],Polygon[{{0,0,(Pi/2)},{(Pi/2),0,0},{(Pi/4),(Pi/4),(Pi/4)}}]}
}],
ParametricPlot3D[(1-s)((1-(a-1)){((Pi )/2),0,0}+(a-1){(Pi/4),(Pi/4),(Pi/4)})+(1-t)s((1-(a-1)){0,((Pi )/2),0}+(a-1){(Pi/4),(Pi/4),(Pi/4)})+(s t)((1-(a-1)){0,0,((Pi )/2)}+(a-1){(Pi/4),(Pi/4),(Pi/4)}),{s,0,1},{t,0,1}],PlotRange->{{0,(Pi/2)},{0,(Pi/2)},{0,(Pi/2)}},Ticks->{Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4],Range[0,Pi/2,Pi/4]},Boxed-> True,Axes->True,ImageSize->600],
ParametricPlot3D[Evaluate[{((Sin[u])/(Cos[v])),((Sin[v])/(Cos[w])),((Sin[w])/(Cos[u]))}/.{u-> (1/4) π (3-a+2 (-2+a) s),v-> (1/4) π (-1+a+4 s-2 a s+2 (-2+a) s t),w-> (1/4) π (-1+a-2 (-2+a) s t)}] ,{s,0,1},{t,0,1},PlotRange->{{0,1},{0,1},{0,1}},Ticks->{Range[0,1,.2],Range[0,1,.2],Range[0,1,.2]},Boxed-> True,Axes->True,ImageSize->600]
}},ImageSize-> 500]
],{{a,.5},0,2}]

Now we substitute the new variables into the integrand

FullSimplify[((1/(1+(x^2) (y^2)(z^2) ))/.{x-> ((Sin[u])/(Cos[v])),y->((Sin[v])/(Cos[w])),z-> ((Sin[w])/(Cos[u]))})]

This expression needs to be multiplied by the absolute value of the determinant of the Jacobian matrix. Thus, the new integrand is

FullSimplify[1/(1+((Tan[u])^2) ((Tan[v])^2) ((Tan[w])^2))(Det[D[{((Sin[u])/(Cos[v])),((Sin[v])/(Cos[w])),((Sin[w])/(Cos[u]))},{{u,v,w}}]])]

Thus, the integral is simply the volume of the polytope that found.

To calculate the volume of the polytope we split it into two pyramids.

One pyramid has vertices (0,0,0), ((π/2),0,0), (0,(π/2),0), (0,(π/2),0). The base of this pyramid is equilateral triangle with the vertices ((π/2),0,0), (0,(π/2),0), (0,(π/2),0) and the height of this pyramid is the line segment with the endpoints (0,0,0), ((π/6),(π/6),(π/6)). Thus the volume of this pyramid is

(1/3)*base*height= (1/3)*(((π^2)(Sqrt[3]))/8)*(π/6)*(Sqrt[3])=((π^3)/48)

One pyramid has vertices (0,0,0), ((π/2),0,0), (0,(π/2),0), (0,(π/2),0),  ((π/4),(π/4),(π/4)). The base of this pyramid is equilateral triangle with the vertices ((π/2),0,0), (0,(π/2),0), (0,(π/2),0) and the height of this pyramid is the line segment with the endpoints ((π/6),(π/6),(π/6)), ((π/4),(π/4),(π/4)). Thus the volume of this pyramid is

(1/3)*base*height= (1/3)*(((π^2)(Sqrt[3]))/8)*(π/12)*(Sqrt[3])=((π^3)/96)

Thus the volume of the polytope is

((π^3)/48)+((π^3)/96) = ((π^3)/32)

Problem 2. Your task

Calculate the famous double integral by using a change of variables similar to what was used to calculate the famous triple integral. Provide all the illustrations as I did in my calculation of the famous double integral.

Problem 3. Cissoid of Diocles

Prolog to Cissoid of Diocles problem

This problem is about the curve called Cissoid of Diocles. In fact this is a family of curves. Below is the construction of the Cissoid of Diocles based on circle with radius one.

Manipulate[Graphics[{
{Thickness[0.002],RGBColor[.75,.75,.75],Line[{{0,0},2{(2/(Sin[θ]))Cos[θ],2}}]},

{Thickness[0.003],RGBColor[0,0,.6],Line[{{-9,2},{9,2}}]},
{Thickness[0.003],RGBColor[0,0,.6],Circle[{0,1}]},
{Thickness[0.002],RGBColor[0.8,0,0],Line[Table[{(2/(Sin[t]))Cos[t],2}-{2Sin[t]Cos[t],2Sin[t]Sin[t]},{t,0.01,Pi-.01,.01}]]},
{Thickness[0.007],RGBColor[1,1,0],Line[{{2Sin[θ]Cos[θ],2Sin[θ]Sin[θ]},{(2/(Sin[θ]))Cos[θ],2}}]},

{Thickness[0.002],RGBColor[0,0,0],Line[{{0,0},{(2/(Sin[θ]))Cos[θ],2}-{2Sin[θ]Cos[θ],2Sin[θ]Sin[θ]}}]},

{PointSize[0.012],RGBColor[0,0,.6],Point[{(2/(Sin[θ]))Cos[θ],2}]},
{PointSize[0.005],RGBColor[0.8,0,0],Table[Point[{(2/(Sin[t]))Cos[t],2}-{2Sin[t]Cos[t],2Sin[t]Sin[t]}],{t,(Pi/128),θ,(Pi/128)}]},
{PointSize[0.012],RGBColor[0.8,0,0],Point[{(2/(Sin[θ]))Cos[θ],2}-{2Sin[θ]Cos[θ],2Sin[θ]Sin[θ]}]},
{PointSize[0.012],RGBColor[0.8,0,0],Point[{0,0}]},
{PointSize[0.012],RGBColor[0,0,.6],Point[{2Sin[θ]Cos[θ],2Sin[θ]Sin[θ]}]}
},PlotRange->{{-5,5},{0,2.3}},Frame->False,Axes->True,Ticks->{Range[-6,6],Range[0,3]},ImageSize->500],{{θ,1/2},(Pi/128),Pi-(Pi/128)}]

Your task

Learn about the Cissoid of Diocles family of curves. The corresponding Wikipedia page is very informative. Based on that information answer the following two questions:

Length

Calculate the length of the part of the Cissoid of Diocles which is inside the circle which is used in the definition of that Cissoid. That is the maroon length in the picture below.

Graphics[{
{Thickness[0.007],RGBColor[0.8,0,0],Line[Table[{(2/(Sin[t]))Cos[t],2}-{2Sin[t]Cos[t],2Sin[t]Sin[t]},{t,Pi/4,3Pi/4,Pi/64}]]},
{Thickness[0.008],RGBColor[0,0,.6],Circle[{0,1}]}

},PlotRange->{{-1.1,1.1},{-0.1,2.1}},Frame->False,Axes->False,ImageSize->400]

In your response to this question you should present and illustrate all the relevant information that you found on the Internet. You should present at least two distinct calculations for the length. The exact value for the length  is expected.

Area

Calculate the area which is below the Cissoid of Diocles and which is inside the circle which is used in the definition of that Cissoid. That is the red area in the picture below.

Graphics[{
{RGBColor[1,0.2,0.2], Polygon[Join[Table[{(2/(Sin[t]))Cos[t],2}-{2Sin[t]Cos[t],2Sin[t]Sin[t]},{t,Pi/4,3Pi/4,Pi/64}],Table[{2Sin[θ]Cos[θ],2Sin[θ]Sin[θ]},{θ,((3 Pi)/4),((5 Pi)/4),(Pi/64)}]]]},
{Thickness[0.007],RGBColor[0.8,0,0],Line[Table[{(2/(Sin[t]))Cos[t],2}-{2Sin[t]Cos[t],2Sin[t]Sin[t]},{t,Pi/4,3Pi/4,Pi/64}]]},
{Thickness[0.008],RGBColor[0,0,.6],Circle[{0,1}]}

},PlotRange->{{-1.1,1.1},{-0.1,2.1}},Frame->False,Axes->False,ImageSize->400]

In your response to this question you should present and illustrate all the relevant information that you found on the Internet. You should present at least two distinct calculations for the area. The exact value for the area  is expected .

Problem 4. Explore Ellipses

Let a and b be positive real numbers. Consider the ellipse

((x^2)/(a^2))+((y^2)/(b^2))=1.

The parametric equation for this ellipse is

{a Cos[t],b Sin[t]},  0≤t≤  2 Pi.

In this problem we consider only the ellipses in this canonical form.

Area

Calculate

Present at least three different ways to evaluate the area enclosed by this ellipse.

Together

The most famous circle is the unit circle. The area enclosed by the unit circle is π. Determine the family of all ellipses each one of which encloses the area π.  Replicate the picture below which shows 40 such ellipses.

Length

Calculate

Determine the exact formula for the circumference of the ellipse introduced in the introduction to this problem. Determine at least three different, but equivalent, ways of writing this formula. Give explanations of the functions that you are using.

Together

The most famous circle is the unit circle. The circumference of the unit circle is 2π.  Determine the family of all ellipses each one of which has the circumference 2π. Replicate the picture below which shows 40 such ellipses.